禁用 SNMP：完整程序示例
简介
本示例适用于 S7-1500 和 S7-1200。
要在项目中使用该程序代码，请按以下步骤操作：
将整个程序代码复制到剪贴板中。
打开文本编辑器（如，“Editor”）。
使用快捷键 Ctrl+V，将剪贴板中的内容粘贴到文本编辑器中。将该文档保存为 scl 文件，如 SNMP_DEACT.scl。
在 STEP 7 中打开项目。
将 scl 文件作为外部源文件进行导入。
生成启动 OB 和数据块。
右键单击该 scl 文件，并在快捷菜单中选择“通过源文件生成块”(Generate block from source)。
在 OB 100 中进行 WRREC 调用的程序示例
DATA_BLOCK "Deactivate_SNMP"
{ S7_Optimized_Access := 'TRUE' }
VERSION : 0.1
NON_RETAIN
VAR
snmp_deactivate : Bool;
snmp_record : Struct
BlockID : UInt;
BlockLength : UInt;
"Version" : USInt;
Subversion : USInt;
Reserved : UInt;
SNMPControl : UDInt;
END_STRUCT;
snmp_done : Bool;
snmp_error : Bool;
snmp_Status : DWord;
END_VAR
BEGIN
snmp_deactivate := true;
snmp_record.BlockID := 16#f003;
snmp_record.BlockLength := 8;
snmp_record."Version" := 1;
END_DATA_BLOCK
ORGANIZATION_BLOCK "Startup"
TITLE = "Complete Restart"
{ S7_Optimized_Access := 'TRUE' }
VERSION : 0.1
BEGIN
REPEAT
"WRREC_DB_1"(REQ := "Deactivate_SNMP".snmp_deactivate,
ID := "Local~PROFINET-Schnittstelle_1",
INDEX := 16#b071,
DONE => "Deactivate_SNMP".snmp_done,
ERROR => "Deactivate_SNMP".snmp_error,
STATUS => "Deactivate_SNMP".snmp_Status,
RECORD := "Deactivate_SNMP".snmp_record);
UNTIL "Deactivate_SNMP".snmp_done OR "Deactivate_SNMP".snmp_error
END_REPEAT;
END_ORGANIZATION_BLOCK
DATA_BLOCK "WRREC_DB_1"
{OriginalPartName := 'WRREC';
VersionGUID := 'bc169451-58cd-44a3-855b-3f78cc0623c8';
S7_Optimized_Access := 'TRUE' }
AUTHOR : SIMATIC
FAMILY : DP
NAME : WRREC
VERSION : 1.0
NON_RETAIN
WRREC
BEGIN
END_DATA_BLOCK
http://shtxjd.cn.b2b168.com
